use Perl

• Benchmarks! (Score:1)

  by Alias (5735)

  So, how MUCH faster? :)
  • I/O dispatch is about 130% faster, since you ask. (Score:1)

    by rcaputo (9040) on 2009.10.15 12:05 (#70900) Homepage Journal

    Sorry, no fancy graphs.

    I wrote a deliberately simple program to count select_read() events per second. I ran it five times for each version of POE, averaged the results, and calculated the improvement using (new_rate/old_rate-1). Standard deviation for the sample sets were about 1%, if that matters.

    #!/usr/bin/env perl
    
    use warnings;
    use strict;
    
    use POE;
    
    my $limit = 10_000;
    my @start_times;
    my @end_times;
    my $count = 0;
    
    my $filehandle;
    
    POE::Session->create(
      inline_states => {
        _start => sub {
          open $filehandle, "<", "/dev/zero" or die $!;
          $_[KERNEL]->select_read($filehandle, "count");
          @start_times = times();
        },
        count  => sub {
          if ($count < $limit) {
            $count++;
            return;
          }
    
          @end_times = times();
          for (0..$#end_times) {
            $end_times[$_] -= $start_times[$_];
          }
    
          $_[KERNEL]->select_read($filehandle, undef);
        },
      },
    );
    
    POE::Kernel->run();
    
    print join("\t", "POE", "BENCH", "COUNT", "RATE"), "\n";
    print join(
      "\t",
      $POE::VERSION,
      "io/cpusec",
      $limit,
      sprintf("%.2f", $limit / ($end_times[0] + $end_times[1])),
    ), "\n";

    I don't have a methodology to test the mark-and-sweep garbage collection in isolation. Got any ideas?

    Reply to This

    Parent