use Perl

• My shot (Score:2)

  by bart (450)

  The only assumption I make is that the files in the list are in sequential order.

  my @keep;
  foreach (@files) {
      @keep = () if /\.copy$/;
      push @keep, $_;
  }
  • Re:My shot (Score:2)

    by grantm (164)

    Of all the suggestions, this one definitely gets my vote for clarity. I did think along the lines of discarding accumulated filenames whenever a '.copy' was encountered but at the time I had grep blinkers on and it can't be done with grep.
• before_incl (Score:1)

  by stvn_skuo (5628)

  
  
  Perhaps try the List::MoreUtils module?

  use List::MoreUtils qw/before_incl/;
  my @keep =
       reverse
       before_incl { /\.copy\z/ }
       reverse @files;
• Unreadable Perl Code (Score:1)

  by Eric Wilhelm (6389)

  ...So what I needed was an algorithm to reduce the above example to just the last two files....

  Or, at least, you want to get the last index of a /\.copy$/ match from the list.

  my $index = (
      grep({$files[$_] =~ m/\.copy$/}
          reverse(0..$#files)
      )
  )[0];
  splice(@files, 0, $index);
  • List::Util improves this (Score:1)

    by Aristotle (5147)

    use List::Util qw( first );
    my $index = first { $files[ $_ ] =~ m/\.copy$/ } reverse 0 .. $#files;
    splice @files, 0, $index if defined $index;
• No need for the flip-flop (Score:1)

  by Aristotle (5147)

  my $seen_full_copy;
  @files = reverse grep { not( $seen_full_copy ||= /\.copy$/ ) } reverse @files;

  The double reverse is still unsightly though.
• There's no fold in List::Util or List::MoreUtils (Score:1)

  by mary.poppins (3530)

  There's a "reduce" in List::Util, but its interface is fairly horribly broken.
  
  Anyway, here's a fold-using implementation:
  
  
use strict;

sub fold {
    my $accum = shift;
    my $code = shift;
    return $accum unless @_;
    return fold( $code->( $accum, shift ), $code, @_ );
}

my @files = qw(
        00000.diff
        00001.diff
        00002.diff
        00003.copy