use Perl

A while ago I needed to know which test modules were the most popular so I could bundle them in Test::Most. I was asked how I figured that out, so I figured I would post the code. I've updated the code to make it a bit more robust, but it's still heuristically based.

First, I need to extract the tests from my minicpan:

#!/usr/bin/perl

use strict;
use warnings;
use CPAN::Mini::Extract;
use Getopt::Long;

GetOptions(
    offline => \my $offline,
    force   => \my $force,
) or exit 1;

my $cpan = CPAN::Mini::Extract->new(
    remote         => 'http://ftp.osuosl.org/pub/CPAN/',
    local          => "$ENV{HOME}/code/minicpan",
    trace          => 1,
    extract        => '/Users/ovid/code/cpanextracted',
    extract_filter => sub { /\.(pm|t)$/ and !/\b(inc)\b/ },
    extract_check  => 1,
    extract_force  => $force,
    offline        => $offline,
);

my $changes = $cpan->run;

I'm also extracting .pm files, but they could be skipped if you don't need them. Then, I run the following, passing it the location of the extracted directory. ($ENV{HOME}/code/cpanextracted/authors/id/). This takes about five minutes to run on my machine.

Note that due to the generic nature of this code, if you have a large project, you could point this at your project directory (assuming it has .t tests) and find out what test modules you're using.

#!/usr/bin/perl

use strict;
use warnings;

use File::Find;
my $target_dir = shift or die "Usage: $0 path/to/modules";

my @tests;

my $time = scalar localtime;
print STDERR "Finding tests.  This may take a while [$time]\n";
find(
    {
        wanted => sub {
            if ( /\.t\z/) {
                push @tests => $File::Find::name;
                warn $File::Find::name if /test.pl\z/;
            }
        },
        nochdir => 0
    },
    $target_dir,
);

my %times_found;

my ( $current, $total ) = ( 1, scalar @tests );

$time = scalar localtime;
print STDERR "Beginning analysis of $total tests [$time]\n";

# test_re must be a star because they might 'use Test;'
my $test_re = qr/\bTest(?:::\w+)*\b/;
foreach my $test (@tests) {
    open my $fh, '<', $test
      or die "Cannot open ($test) for reading: $!";

    if ( !( $current % 1000 ) ) {
        my $time = scalar localtime;
        print STDERR "Processing $current out of $total test programs at [$time]\n";
    }
    $current++;
    while ( my $line = <$fh> ) {
        next if $line =~ /^\s*#/;    # skip comments
        if ( $line =~ /^\s*(?:use|require)\s+($test_re)/ ) {
            $times_found{$1} ||= 0;
            $times_found{$1}++;
        }
    }
    close $fh or die "Cannot close ($test): $!";
}

for my $module ( sort { $times_found{$b} <=> $times_found{$a} }
    keys %times_found )
{
    printf "%-70s  %6d\n", $module, $times_found{$module};
}

The results are a bit different then before because I've updated my regex to include "required" modules. Here's the new top 20, along with the number of times each was seen.

1. 69396 - Test::More
2. 10912 - Test
3. 2314 - Test::Exception
4. 962 - Test::Simple
5. 610 - Test::Base
6. 386 - Test::NoWarnings
7. 308 - Test::Builder::Tester
8. 254 - Test::Deep
9. 223 - Test::Pod
10. 217 - Test::Warn
11. 213 - Test::Differences
12. 187 - Test::MockObject
13. 157 - Test::Pod::Coverage
14. 131 - Test::Builder
15. 118 - Test::WWW::Mechanize::Catalyst
16. 113 - Test::XML
17. 112 - Test::Block
18. 110 - Test::Perl::Critic
19. 107 - Test::Distribution
20. 101 - Test::SQL::Translator

All told, I found 373 test modules used.